To sum up licensing, it is the part where you sell your flash game to a sponsor. For that they pay you an interesting amount of money, and if they have it exclusively your earnings are more. What you are supposed to do is add their logo and their link into your game, and give the swf to them. They also may accept your ads. The fact is that licensing is a one time pay job, but it has the potential of big earnings. It also needs a lot of waiting time, about 2 months, to get a fair offer. If you happen to get interested check out Flash Game License. That’s it for licensing.

Advertisements is the part that I’ve been working on. I’ve been publishing games through Mochi, and Kongregate so far. My games aren’t big, just simple. A space invaders game, a hangman, quizzes, and more. One game stats of these simple games for 1 month are about ~3.000 players, ~7.000 impressions (how many times the ads have been viewed) and 1.2$ earnings. Stats differ from service to service since players choose these respectively for the games that they have to offer. Try to view some games, the date they’ve been published and the total views they have to figure out what is interesting and what is not. My take on that is quantity over quality, and that’s why I said simple games. Their quality is good, they are just classic games that you’ve surely have seen again so far. Development times are smaller, more titles come up every month that raise your total revenue.

Tricks that you can use, is first being a publisher by yourself. You can create your own website (try blogger for example), and post there your games. That way you can create a community by yourself which will play your games. Be warned though, that creating a community is hard job and takes a lot of time and devotion. Mochi also supports publishers by sharing a 10% of their revenue, if you host by yourself the games’ files. Another classic trick is adding a ‘More games’ button that will open a page with more games from you. That way you ‘recycle’ players which generate more impressions.

Cons

Both Mochi and Kongregate have a limit which you must pass to take your money. 100$ earnings for Mochi, 25$ for Kongregate. If you make your calculations you’ll need to invest a fair amount of time to reach these goals. Even if you at last achieve it, you’ll have to wait for a month before you get approval to take your money.

How to upload games to Mochi

For Mochi its simple. After you register you’ll find in your Dashboard a Setup New Game button.

Add new game page.

Then just upload your game files. You will be introduced to a variable to authenticate your game. Just type

public var _mochiads_game_id:String = "yourstringhere123";

and then

MochiServices.connect(_mochiads_game_id, root);

in your games’ constructor.

Upload files.

After uploading you’ll have to wait for 24 hours until the game gets accepted for Distribution. The same goes for patching up your game. You’ll need to provide icons and a description for that.

How to upload games to Kongregate

While you’re logged in, got to the top right of the page, open the pop up menu of your profile and click on the Upload A Game option.

Create new game in Kongregate.

After that you must upload your files and set up your stats if you use.

Uploading files and settings statistics in Kongregate.

Well, that’s it. Next I’m planning on trying for licensing, just to check it out.

48 HOURS? R U SERIOUS? NO MONEY? OPEN SOURCE? Well yes. 21 times now it worked, why not now :P ? It’s a really well known contest. The famous Notch (creator of Minecraft) is taking part in the last ones, and others like Chevy Ray, Sophie Houlden and other known indie developers. I always expected those taking part in the contest writing endless hours code, not eating, not sleeping, just CODE. Many times I have wondered the feeling of it, so I decided to take part in the 22nd contest. Unfortunately, things in my calendar didn’t go exactly well, and I lost the Saturday. Not until late Sarurday did I find out the the contest was running….

At Sunday I was really frustrated by that and I kept watching screencasts by Notch, and Sophie Houlden with their games. A friend in msn told me to do something. I was like “What?”, so he proposed to me his story. You are in a room full of robots and you must do exactly what they do in order to trick them and not spot you. It was a really nice idea, and I had about 16 hours to make it happen, so I started right away.

I used FlashDevelop and FlashPunk since that’s the tools I’ve been used to. No time to learn others… Graphics created with Pixlr, music with sfxr, background music found in the web a free copyright, and edited in Audacity (though i feel I sould have created it myself even if it would be worse :( ). Actionscript combined with FlashPunk made the development process a piece of cake. Also sfxr saved me a TON of time for the sound effects. While I was developing my game I’ve also run screencasts which you can find on my channel at twitchtv. As for the graphics when I made the robots I wanted to create a spritesheet with them and TexturePacker was the right tool for that. Lucky for me I am an open source developer (thanks to ISS) so I had already acquaired my free license :).

The development of Alone with Robots (the name a picked for the game) went really smooth. Having already developed 5 games in FlashPunk I had some library-written code, for example the floating text was already created, sound management, and a particle system from ISS. Unfortunately family issues have disturbed that process. I went outside to the pharmacy, shopped from the market and when I returned I dropped everything and continued my game like a freak. The screencasting also went really well, I had up to 7 viewers at a time, watching my screen full of code and graphics, which is nice for a noob like me. At 2 hours left, I had finished it and started polishing. I’ve added achievements which I haven’t ever done in my games! A screencast viewer also said to me to polish more the achievements, and make them more flashy! At first I didn’t like the idea but later on it proved himself right!

The process of uploading was piece of cake. Alone with Robots got up to Kongregate, source code can be found in my profile @ github. And @ Ludum Dare you can find my entry.

Conclusion

Ludum Dare was the best experience I’ve ever had in game development so far. It helped me improve my time management skills with deadlines, calculating my priorities in development for the features I wanted, fast coding, test my programming skills, improving my art/sound skills (I really liked the way I made hearts. Finally!), even learn knew things (achievements in this case) or the calculation of score which was done by luck and I liked it xD, and finally the best, I know my limits better that before the contest! I know what I can do and what I can not, in a certain amount of time. The screencasts were for themselves a lot of pressure since I didn’t want my viewers watch nothing but mistakes :P . I think I matured a lot from this contest.

I was really happy with what I’ve achieved and surely my next Ludum Dare entry will be a lot better ;) . But until then, it’s rating time! Next Ludum Dare will be in 4 months so I’ll have improved a lot until then.

I’ve used Inkscape, and what  I really liked is the part that vector graphics can be easily manipulated to any dimensions without worries. Rotated, scaled, positioned with lossless quality, easy, thanks to Inkscape. I’ve grown to love it in a matter of hours (yeah, I was free that day).

As a programmer I’ve always wanted high quality graphics for my games but it was even harder finding prototypes. That said I was never satisfied with the result. And of course I couldn’t pay for professionals. Luckily I had patient friends… For start I’ve used graphics from Moosader, a nice portal with free (as in freedom) art with no copyrights. That helped me a lot with my prototypes. But later on I couldn’t release the game with those graphics.

So here came vector graphics and the above tutorial I found :D . I’ve created lots of graphics for test with very lovely results. Not characters though, I was afraid to try, but soil, wall, and crates were very easy. I’ve even managed to make them tilable, so you can easily create a continuous environment. As said, you can scale them, position and rotate them as you want. You can even try my own graphics, they are free, just remember to mention me in your credits please :)

I’ve always wanted to create a platform game. Now there is one less reason for not trying…. there are a couple more though :P But in any case, if you ever want to create graphics check it out ;) Being a programmer and not an artist guy it helped me a lot.

Update 1: Seems that there is a bunch of these tutorials @ 2D Game Art for Programmers. Thanks to SpriteAttack!

package worlds.objs
{
	import net.flashpunk.Entity;
	import net.flashpunk.graphics.Text;
	import net.flashpunk.graphics.Graphiclist;
	import net.flashpunk.utils.Input;
	/**
	 * ...
	 * @author Konstantinos Egarhos
	 */
	public class Menu_Obj extends Entity
	{
		protected var title:Text;
		protected var selection:Array;
		protected var back:Text;
		protected var returnBack:Boolean; // When text back is highlighted.
		protected var selected:Menu_Obj; // Returns the menu to which to change the screen.
		public var updates:Boolean; // When false the player can't press enter to choose the same option probably because the screen is doing something.
		protected var menu:Graphiclist;
		private var choice:Number = 1;
		protected var focus:Boolean; // To lose focus if no choice has been selected.
		public var fadeIn:Boolean;
		public var fadeOut:Boolean;

		// Gets-Sets
		public function get returnBackG():Boolean
		{
			return returnBack;
		}
		public function get choiceG():Number
		{
			return choice;
		}
		protected function set choiceS(setValue:int):void
		{
			if (setValue == 0)
			{
				choice = 0;
			}else
			{
				choice += setValue;
				if (choice < 0)
				{
					choice = 0;
				}else if (choice > selection.length -1)
				{
					choice = selection.length -1;
				}
			}
		}
		protected function set choiceSM(setValue:int):void
		{
			choice = setValue;
		}
		public function get selectedG():Menu_Obj
		{
			return selected;
		}
		public function set selectedS(setValue:Menu_Obj):void
		{
			selected = setValue;
		}

		public function Menu_Obj()
		{
			selected = null;
			updates = true;
			returnBack = false;
		}

		override public function update():void
		{
			if (selected == null && updates)
			{
				checkInput();
			}
		}

		/**
		 * Checks the input.
		 */
		public function checkInput():void
		{
			/*if (Input.pressed("down"))
			{
				Text(selection[choiceG]).alpha = 0.5;
				choiceS = 1;
				Text(selection[choiceG]).alpha = 1;
			}
			else if (Input.pressed("up"))
			{
				Text(selection[choiceG]).alpha = 0.5;
				choiceS = -1;
				Text(selection[choiceG]).alpha = 1;
			}*/

			focus = false;

			for (var i:uint = 0; i < selection.length; i++)
			{
				if (Input.mouseX >= Text(selection[i]).x && Input.mouseX <=  Text(selection[i]).width + Text(selection[i]).x)
				{
					if (Input.mouseY >= Text(selection[i]).y && Input.mouseY <=  Text(selection[i]).height + Text(selection[i]).y)
					{
						focus = true;

						if (choiceG != i)
						{
							for (var j:uint = 0; j < selection.length; j++)
							{
								if (j != i)
								{
									Text(selection[j]).alpha = 0.5;
								}else
								{
									Text(selection[j]).alpha = 1;
									choiceSM = j;
								}
							}
						}
					}
				}
			}
			if (back != null)
			{
				if (Input.mouseX >= Text(back).x && Input.mouseX <= Text(back).x + Text(back).width)
				{
					if (Input.mouseY >= Text(back).y && Input.mouseY <= Text(back).y + Text(back).height)
					{
						focus = true;
						if (Text(back).alpha != 1)
						{
							Text(back).alpha = 1;
							returnBack = true;
						}
					}else
					{
						if (Text(back).alpha != 0.5)
						{
							Text(back).alpha = 0.5;
							returnBack = false;
						}
					}
				}
			}

			if (!focus)
			{
				for (var d:uint = 0; j < selection.length; j++)
				{
					if (Text(selection[j]).alpha != 0.5)
					{
						Text(selection[j]).alpha = 0.5;
					}
				}
				if (choiceG != 100)
				{
					choiceSM = 100;
				}
			}
		}
	}
}

and here is how to use it. This is the difficulty selection screen.

package worlds.objs
{
	import net.flashpunk.FP;
	import net.flashpunk.graphics.Graphiclist;
	import net.flashpunk.graphics.Text;
	import net.flashpunk.utils.Input;
	import worlds.Level;
	/**
	 * ...
	 * @author Konstantinos Egarhos
	 */
	public class DifSel_Obj extends Menu_Obj
	{

		public function DifSel_Obj()
		{
			selection = new Array();
			selected = null;
			title = new Text(String("Select Difficulty"));
			title.font = 'FONT_TITLE';
			title.align = "center";
			title.size = 20;
			title.x = FP.halfWidth - title.width / 2;
			title.y = 20;
			title.color = 0x32cd32; // Dark Green
			menu = new Graphiclist(title);
			updates = true;

			selection.push(new Text(String("Normal")));
			selection.push(new Text(String("Brutal")));

			for (var i:uint = 0; i < selection.length; i++)
			{
				Text(selection[i]).font = 'FONT_CHOICE';
				Text(selection[i]).size = 16;
				Text(selection[i]).align = "center";
				Text(selection[i]).x = FP.halfWidth - Text(selection[i]).width / 2;
				Text(selection[i]).y = FP.height / (selection.length + 1) * (i + 1);
				Text(selection[i]).color = 0xFFFFFF; // White
				Text(selection[i]).alpha = 0.5;
				menu.add(selection[i]);
			}

			back = new Text(String("back"));
			Text(back).font = 'FONT_CHOICE';
			Text(back).size = 10;
			Text(back).x = 5;
			Text(back).y = FP.height - (Text(back).height);
			Text(back).color = 0x00CC00;
			Text(back).alpha = 0.5;
			menu.add(back);

			Text(selection[0]).alpha = 0.5;

			fadeIn = fadeOut = false;

			choiceS = 0;
			graphic = menu;
		}

		override public function update():void
		{
			super.update();
		}

		override public function checkInput():void
		{
			super.checkInput();

			if (Input.pressed("enter") || Input.mousePressed)
			{
				switch (choiceG)
				{
					case 0:
						fadeOut = true;
						FP.alarm(1, normalGame);
						Log.CustomMetric("Normal", "difficulty");
						updates = false;
						break;
					case 1:
						fadeOut = true;
						FP.alarm(1, brutalGame);
						Log.CustomMetric("Brutal", "difficulty");
						GlobalVariables.BRUTALSCORE = 0;
						updates = false;
						break;
					default:
						break;
				}
			}
		}

		/**
		 * Starts level 1 from normal difficulty.
		 */
		public function normalGame():void
		{
			FP.world = new Level(1,false);
		}

		/**
		 * Starts level 1 from brutal difficulty.
		 */
		public function brutalGame():void
		{
			FP.world = new Level(1, true);
		}
	}

}

Explanation: The menu system consists of three text objects. Title – the title of the menu, selection – an array of text objects those that can be selected by player, back – the back button. Variable selected is another menu_Obj class which takes the next menu to change this one. The way it is changed is out of the scope of this class but what i did was create it to the right outside from view and then move both to the left. Next recycle that one.

Sometimes i didn’t want to have these functions e.g. the Leaderboards didn’t have choices. That’s when I overrided the updates and replaced it with an empty update function. Generally I wanted to have and an icon for sound mute, but i didn’t make it, though i advise you to make something like it.

Some things changed during the last release. The assets were changed again to make the game have one solid graphic style (thanks to Theodore Barlas). I made menus clickable with the mouse, and added a back button at the bottom left. I had plans to make a button that would mute the sound but I decided not to, and I can’t remember why…. After that the time came to upload it.

I’ve planned to release my game on Mochi. Mochi is a semi-amazing network of flash games. The amazing is that it provides a wonderful API for tracking players, stats, scores and above all, it obfuscates (encrypts) the code for evil swf decompilers. I chose to have a preloader ad, that would preload my game instead of creating a preloader myself and also make me money. So I uploaded my game, and awaited authorization.

But, ach, mein Gott (as Helsing sais), you can never trust the developer to do a satisfying beta testing. ISS had a big bug. In main menu by giving access to mouse, I’ve destroyed keyboard input. In case a player would tap the keyboard in main menu it would simply froze. I would never pass the Quality Assurance of Mochi with that. I wondered how did it skip me, but I immediately fixed it by removing at all the keyboard in main menu. The bad thing was that I COULDN’T CHANGE THE BUILD I SENT TO MOCHI! So I was sure of my first try to be a failure.

Oddly enough, that did not happen. Next day afternoon I’ve received a nice email that said politely that my game passed QA and I was ready for monetization. Hardly believing it I logged in and immediately changed my build with version 1.1 . And I finally was ready ‘-) . Glad as never I sitted hours in front of my monitor watching the stats going high.

AND THERE WAS IT!

I’ve just made my first 0.01$ from making games! I couldn’t even believe it, and almost cried. I continued sitting in front of my monitor watching the stats, and as time reached 02.00 am I’ve seen my 2nd cent!! Being hyperactive at that moment I’ve stared at my monitor for hours, looking at my source code removing and adding and fixing code from mochi API. Reality is a bitch however but thankfully not for my game. I had to do some real work which I’ve totally quitted that day, so I decided to get some sleep and wake up early.

The other day, I’ve opened my computer to do some work, logged in mochi and saw my 3rd cent! Being like –>OMG<–, I’ve advertised my game everywhere. Twitter, G+, Facebook. Friends have helped a lot by sharing my posts. That day I made an extra 5 cents, and between fun and reality I’ve wondered if this is how it’ll go, making 5 to 10 cents a day. I’ve really had to make a dozen of more games and to do that I had to make that my everyday life occupancy, which was not bad as an option….

I would host my game here but unfortunately WordPress doesn’t allow flash, so here’s the link.

Home page of ISS in Mochi.

I’ll make some more posts about other flash game networks since I’ve released my game to others. Also I’ll tell you how much money I make now to contrast it with your everyday job in another post (not so much so don’t get excited), and I hope to help you for your first steps in game development as indie (indies FTW, I’ve really grown to love that philosophy). The technical posts on FlashPunk will also continue to come.

Until then, its time to code some games again baby….

The changes in Beta 02 were massive, and I didn’t release my game that time as I was intending to (thank God!!!). At that time I’ve begun and my notorious PR campaign by advertising my game everywhere (for example this devlog) :D

The players changelog (so I call the changelog that interests the users without the techy stuff) was

• Improved Main Menu
• Changed resolution from 800×600  to 640×480 - That was done mostly to make the game more browser-based. No one would accept an 800×600 resolution.
• Score is based from the effectiveness of the player, his accuracy and his remaining life. - Gives replay value to the game.
• In case the swf looses focus from the user the game automatically pauses. - That is done in case the user is multitasking e.g. his boss just appeared behind him.
• Added a settings menu.
• Mouse can be activated to play. - That is done also for multitasking e.g. the user is talking to the phone.
• Added a highscore screen.
• From pause screen the player can return to main menu. - At last….
• Player’s life is an image. - Nothing better than easier ways to spot the situation the player is on.
• Sounds can be muted. - No one would ever accept a game where he can’t mute the sound.
• Redesigned levels. - Here you are alekos :P (the game was obviously way too hard).
• Smaller size. - I’ve made the music lower bit ratio. It really didn’t have to be that high. The game is at half the size and quicker loaded.
• Better performance - It’s always good to have more FPS for third world computers. More players!

Level 7 of beta 02 in original resolution. Clearly better fitted for a webpage.

Graphics remained as they were unfortunately. But that was to be fixed at next release. The game now seemed a lot better thanks to the swearing of one of my friends that got me motivated :)

There were still some bugs here and there, but a great deal of them was fixed, and I finally had a semi-nice game.

swf can be found here. And with this I was one step closer to the release.

And for my PR I’ve then started to say “Comments are not welcome, they are required” :D . So make a comment!!

Διαβάζοντας ξανά τις ειδήσεις της ημέρας (έχω κόψει την τηλεόραση εδώ και πολύ καιρό) έχω αρχίσει να συνειδητοποιώ πως μου κάνει κακό. Ίσως θα έπρεπε να τις κόψω όπως όταν τις είχα κόψει παλαιότερα για ένα διάστημα, όταν διάβαζα τις ειδήσεις καλή ώρα όπως τώρα και η διάθεσή μου πήγαινε στράφι για το υπόλοιπο της ημέρας, και αυτό γινόταν καθημερινά. Δεν μπορούσα να ζήσω έτσι. Απ’την άλλη τώρα μπορώ. Ίσως φταίει το ότι ελπίζω πως απ’όλα αυτά νομίζω πως τελικά θα κάνουμε την επανάστασή μας στο τέλος και τα πράγματα θα βελτιωθούν. Ή τελικά έχω αναπτύξει μια απάθεια, ίσως φταίει και αυτό.

Η γενιά της μεταπολίτευσης λοιπόν, η γενιά του Πολυτεχνείου φαίνεται πως φταίει για όλα. Εμείς είμαστε καλύτεροι; Μπα. Απ’την άλλη δεν νομίζω πως είναι η γενιά του Πολυτεχνείου. Απλά λάθος άνθρωποι από αυτή την γενιά επιλέχθηκαν. Θα επιλέξουμε όμως εμείς καλύτερους; Σκατά, μέχρι και ο Πούτιν που είναι και γαμώ τους Πρωθυπουργούς και θαυμάζω, είναι μπλεγμένος μέσα στην διαφορά, αλλά αυτόν κανείς δεν τον πειράζει και περιέργως έχει καταφέρει να κάνει καλό στην χώρα του… Μάλλον τελικά πρέπει να πάψω να ασχολούμαι με την πολιτική. Ίσως έτσι να νοιώσω καλύτερα.

… γιατί να υπάρχουν άνθρωποι που να θέλουν εξουσία; Ναι κατάντησα και γω φιλόσοφος μου φαίνεται… Ίσως φταίει που εγώ δεν έχω πισίνα και κάθε μέρα πρέπει να μαγειρεύουμε στο σπίτι αντί να μας μαγειρεύει κάποιος άλλος ενώ εγώ θα ασχολούμαι με πιο σημαντικά πράγματα. Θα μπορούσα για παράδειγμα να είχα επιχειρήσεις σε όλο τον κόσμο. Τότε θα με ενδιέφερε τι γίνεται; Άλλωστε δεν είναι η φτώχεια που δοκιμάζει τον άνθρωπο. Στην φτώχεια η λογική της επιβίωσης είναι η μόνη που ισχύει. Τα πλούτη είναι αυτά που δείχνουν το πραγματικό πρόσωπο κάποιου, γιατί μόνο τότε ο άνθρωπος είναι ελεύθερος να κάνει όπως εκείνος νομίζει σε αυτόν τον κόσμο.

Χμ, δεν είμαι πλούσιος, απλά ένας ακόμα τραγικός κάτοικος αυτής της χώρας ο οποίος δεν θέλει να την εγκαταλείψει(μάλλον φοβάται και δεν έχει καταλάβει ακόμα τι τον περιμένει εδώ). Η λογική της επιβίωσης δεν με έχει επηρεάσει ακόμα. Κακώς, θα έπρεπε να της επιτρέψω να βγει στην επιφάνεια. Έτσι θα γίνω πιο βίαιος και δεν θα κάνω αφελής δημοκρατικούς διαλόγους ούτε και θα γράφω σε αυτό το blog χωρίς να καταφέρνω απολύτως τίποτα.

Η ώρα πήγε 11 παρά 10 και πρέπει να αρχίσω να ετοιμάζομαι για την συνέλευση του συλλόγου δημιουργών λογισμικού ψυχαγωγίας. Αναρωτιέμαι αν θα είναι διαφορετικό από την πολιτική…

EDIT: SoundSystem now has a repository with bug fixes. Find it here.

So without further ado, here’s the code:

package
{
	import net.flashpunk.FP;
	import net.flashpunk.Sfx;
	import net.flashpunk.tweens.sound.Fader;
	/**
	 * ...
	 * @author Konstantinos Egarhos
	 */
	public class SoundSystem
	{
		private static var mute:Boolean;
		private static var volume:Number; // From 0 to 1.
		private static var snd:Sfx;
		private static var fader:Fader;

		// Gets-Sets
		public static function get muteG():Boolean
		{
			return mute;
		}

		/**
		 * Constructor of a static class.
		 */
		public function SoundSystem()
		{

		}

		/**
		 * Sets mute to false, and volume to 0.7.
		 */
		public static function reset():void
		{
			mute = false;
			volume = 0.7;
			setVolume();
			fader = new Fader(resetVolume);
		}

		/**
		 * Resets volume.
		 */
		public static function resetVolume():void
		{
			FP.volume = volume;
		}

		/**
		 * Adds the fader(in case the world is changed).
		 */
		public static function addFader():void
		{
			FP.world.addTween(fader);
		}

		/**
		 * Sets the volume, or if it's muted it zeroes it.
		 */
		public static function setVolume():void
		{
			if (mute)
			{
				FP.volume = 0;
			}else
			{
				FP.volume = volume;
			}
		}

		/**
		 * Returns the pan value according to the entity x position in the stage.
		 * @param	xPos The x position where the sound is comming.
		 * @return The pan value.
		 */
		public static function panSound(xPos:Number):Number
		{
			if (xPos > FP.halfWidth)
			{
				xPos -= FP.halfWidth;
				return xPos / FP.halfWidth;
			}else if(xPos < FP.halfWidth)
			{
				return (xPos/FP.halfWidth)-1;
			}else
			{
				return 0;
			}
		}

		/**
		 * Plays sounds.
		 * @param	snd The sound you want to hear.
		 * @param	xPos The source of the sound in the x axis for panning.
		 */
 		public static function play(snd:Sfx, xPos:Number = 320):void
		{
			if (!mute)
			{
				snd.play(volume, panSound(xPos));
			}
		}

		/**
		 * Loops sounds.
		 * @param	snd The sound you want to hear.
		 * @param	xPos The source of the sound in the x axis for panning.
		 */
		public static function loop(snd:Sfx, xPos:Number = 320):void
		{
			if (!mute)
			{
				snd.loop(volume, panSound(xPos));
			}
		}

		/**
		 * Pauses the sound from playing.
		 * @param	snd The sound you want to pause.
		 */
		public static function pause(snd:Sfx):void
		{
			snd.stop();
		}

		/**
		 * Mutes or unmutes the sounds.
		 */
		public static function reverseMute():void
		{
			if (mute)
			{
				mute = false;
			}else
			{
				mute = true;
			}
			setVolume();
		}

		/**
		 * Increases/decreases gradually to targetVolume all the sounds.
		 * @param	targetVolume The volume to be set.
		 * @param	time The duration the change will take.
		 */
		public static function fadeOut(targetVolume:Number, time:Number):void
		{
			fader.fadeTo(targetVolume, time);
		}

	}

}

The class is considered as “static”. Of course no such thing exists in actionscript but its easier to describe it that way. Every function is static in order to be called from other parts of the code with ease. e.g.

SoundSystem.reset(); // Initializes. Just once in your code.

SoundSystem.play(soundExplosion, this.centerX); // where this.centerX is the enemies position

The function panSound() is called from every other function except from the one that plays the background sound. It’s rather simple, though I’m a little proud for that little masterpiece :D. The pan value can be a float number from -1(left) to +1(right). So in the function we have to first find if the sound source is past the center or not, and that’s what the if-else if-else do. The division of a value to its full returns a value from 0 to 1, and that’s saficient for the first if which takes place if the source is in the right hand of the stage. As for the left this was rather tricky but simple. We take the same result but subtract it with 1, in order to have the exact same result in its minus form!

As for the reverseMute() function its here for the settings only. The user can choose to mute or unmute the sound, and by this function it is done.

You’ll have to call addFader() in each world initialization if you want to fade the sound in that world. Careful here, if you forget it probably you won’t have the result you want, and the sound will still play without giving you an error.

The only thing you have to care about this class is the default value of the xPos. Your game maybe will have different dimensions than mine, so though its a very rare occation to be exactly in the middle, you probably won’t want to miss that.

package
{
	import net.flashpunk.Entity;
	import net.flashpunk.FP;
	import net.flashpunk.Graphic;
	import net.flashpunk.graphics.Graphiclist;
	import net.flashpunk.graphics.Image;
	import net.flashpunk.graphics.Text;
	import net.flashpunk.tweens.misc.NumTween;
	import net.flashpunk.utils.Ease;

	/**
	 * ...
	 * @author Konstantinos Egarhos
	 */
	public class FloatingText extends Entity
	{
		public var title:Text;
		public var speed:int;
		public var image:Image;
		public var duration:Number;
		public var timeElapsed:Number;
		public var alpha:NumTween;

		/**
		 * Creates a floating text.
		 */
		public function FloatingText()
		{
			title = new Text("");
			title.font = 'FONT_STATS'; // A font variable.
			speed = 50;
			super();
		}

		/**
		 * Fades the floating text, and lifts it up.
		 */
		override public function update():void
		{
			title.alpha = alpha.value;
			this.y -= speed * FP.elapsed;
		}

		/**
		 * Recycles the floating text.
		 */
		public function disappeared():void
		{
			FP.world.recycle(this);
		}

		/**
		 * Resets the floating text.
		 * @param	x Location in the x (right-left) axis.
		 * @param	y Location in the y (top-bottom) axis.
		 * @param	text The number concatenated with a '+' in front.
		 * @param	duration The time it takes to fade out.
		 */
		public function reset(x:Number,y:Number, text:String, duration:Number=0.6):void
		{
			title.text = String("+" + text);
			this.duration = duration;
			timeElapsed = 0;
			title.color = 0x999999;
			title.size = 18;
			alpha = new NumTween(disappeared);
			alpha.tween(1, 0, duration, Ease.cubeIn);
			addTween(alpha);
			graphic = new Graphiclist(title);
			this.x = x - title.width / 2;
			this.y = y - title.height / 2;
		}

	}

}

The function disappeared() recycles the floating text when its called. Its not removed since the remove function would take much more processing power than recycle. Garbage collector will deal with this. Respectively the function reset(), adds the floating text onto the stage. It’s not used in the constructor because the Floating text gets recycled and not created, so the text already has these values and we need to set them again.

We set the text, duration, reset the time, the color (in case we need different, I didn’t), the size (the bigger the enemy gets but I didn’t use it), the NumTween which sets to call function disappeared() when its done fading out, and we finally start the tween, add it, set the graphic, and the location x,y.

In my code I call it with

FloatingText(world.create(FloatingText)).reset(this.x + this.halfWidth, this.y+halfHeight, points.toString()); // Where points are the score the player gets.